Include vim configuration

15 files changed, 536 insertions, 0 deletions

diff --git a/.vim/autoload/pathogen.vim b/.vim/autoload/pathogen.vim
new file mode 100644
index 0000000..59a75c1
--- /dev/null
+++ b/.vim/autoload/pathogen.vim
@@ -0,0 +1,353 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.4
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#interpose() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround().  Curly braces are expanded with pathogen#expand():
+" "bundle/{}" finds all subdirectories inside "bundle" inside all directories
+" in the runtime path.
+function! pathogen#infect(...) abort
+  for path in a:0 ? filter(reverse(copy(a:000)), 'type(v:val) == type("")') : ['bundle/{}']
+    if path =~# '^\%({\=[$~\\/]\|{\=\w:[\\/]\).*[{}*]'
+      call pathogen#surround(path)
+    elseif path =~# '^\%([$~\\/]\|\w:[\\/]\)'
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#surround(path . '/{}')
+    elseif path =~# '[{}*]'
+      call pathogen#interpose(path)
+    else
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#interpose(path . '/{}')
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  if pathogen#is_disabled($MYVIMRC)
+    return 'finish'
+  endif
+  return ''
+endfunction
+
+" Split a path into a list.
+function! pathogen#split(path) abort
+  if type(a:path) == type([]) | return a:path | endif
+  if empty(a:path) | return [] | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction
+
+" Convert a list to a path.
+function! pathogen#join(...) abort
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort
+  return call('pathogen#join',[1] + a:000)
+endfunction
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() abort
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction
+
+" Check if a bundle is disabled.  A bundle is considered disabled if its
+" basename or full name is included in the list g:pathogen_blacklist or the
+" comma delimited environment variable $VIMBLACKLIST.
+function! pathogen#is_disabled(path) abort
+  if a:path =~# '\~$'
+    return 1
+  endif
+  let sep = pathogen#slash()
+  let blacklist =
+        \ get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', [])) +
+        \ pathogen#split($VIMBLACKLIST)
+  if !empty(blacklist)
+    call map(blacklist, 'substitute(v:val, "[\\/]$", "", "")')
+  endif
+  return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
+endfunction
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  Curly braces are expanded with pathogen#expand().
+function! pathogen#surround(path) abort
+  let sep = pathogen#slash()
+  let rtp = pathogen#split(&rtp)
+  let path = fnamemodify(a:path, ':s?[\\/]\=$??')
+  let before = filter(pathogen#expand(path), '!pathogen#is_disabled(v:val)')
+  let after = filter(reverse(pathogen#expand(path, sep.'after')), '!pathogen#is_disabled(v:val[0:-7])')
+  call filter(rtp, 'index(before + after, v:val) == -1')
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  Curly braces are expanded with pathogen#expand().
+function! pathogen#interpose(name) abort
+  let sep = pathogen#slash()
+  let name = a:name
+  if has_key(s:done_bundles, name)
+    return ""
+  endif
+  let s:done_bundles[name] = 1
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      let list += reverse(filter(pathogen#expand(dir[0:-6].name, sep.'after'), '!pathogen#is_disabled(v:val[0:-7])')) + [dir]
+    else
+      let list += [dir] + filter(pathogen#expand(dir.sep.name), '!pathogen#is_disabled(v:val)')
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction
+
+let s:done_bundles = {}
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort
+  let sep = pathogen#slash()
+  for glob in pathogen#split(&rtp)
+    for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
+      if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
+        silent! execute 'helptags' pathogen#fnameescape(dir)
+      endif
+    endfor
+  endfor
+endfunction
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction
+
+" Section: Unofficial
+
+function! pathogen#is_absolute(path) abort
+  return a:path =~# (has('win32') ? '^\%([\\/]\|\w:\)[\\/]\|^[~$]' : '^[/~$]')
+endfunction
+
+" Given a string, returns all possible permutations of comma delimited braced
+" alternatives of that string.  pathogen#expand('/{a,b}/{c,d}') yields
+" ['/a/c', '/a/d', '/b/c', '/b/d'].  Empty braces are treated as a wildcard
+" and globbed.  Actual globs are preserved.
+function! pathogen#expand(pattern, ...) abort
+  let after = a:0 ? a:1 : ''
+  if a:pattern =~# '{[^{}]\+}'
+    let [pre, pat, post] = split(substitute(a:pattern, '\(.\{-\}\){\([^{}]\+\)}\(.*\)', "\\1\001\\2\001\\3", ''), "\001", 1)
+    let found = map(split(pat, ',', 1), 'pre.v:val.post')
+    let results = []
+    for pattern in found
+      call extend(results, pathogen#expand(pattern))
+    endfor
+  elseif a:pattern =~# '{}'
+    let pat = matchstr(a:pattern, '^.*{}[^*]*\%($\|[\\/]\)')
+    let post = a:pattern[strlen(pat) : -1]
+    let results = map(split(glob(substitute(pat, '{}', '*', 'g')), "\n"), 'v:val.post')
+  else
+    let results = [a:pattern]
+  endif
+  let vf = pathogen#slash() . 'vimfiles'
+  call map(results, 'v:val =~# "\\*" ? v:val.after : isdirectory(v:val.vf.after) ? v:val.vf.after : isdirectory(v:val.after) ? v:val.after : ""')
+  return filter(results, '!empty(v:val)')
+endfunction
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#slash() abort
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction
+
+function! pathogen#separator() abort
+  return pathogen#slash()
+endfunction
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
+endfunction
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction
+
+" Section: Deprecated
+
+function! s:warn(msg) abort
+  echohl WarningMsg
+  echomsg a:msg
+  echohl NONE
+endfunction
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.  Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) abort
+  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#infect('.string(a:path.'/{}').')')
+  return pathogen#surround(a:path . pathogen#slash() . '{}')
+endfunction
+
+function! pathogen#incubate(...) abort
+  let name = a:0 ? a:1 : 'bundle/{}'
+  call s:warn('Change pathogen#incubate('.(a:0 ? string(a:1) : '').') to pathogen#infect('.string(name).')')
+  return pathogen#interpose(name)
+endfunction
+
+" Deprecated alias for pathogen#interpose().
+function! pathogen#runtime_append_all_bundles(...) abort
+  if a:0
+    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#infect('.string(a:1.'/{}').')')
+  else
+    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#infect()')
+  endif
+  return pathogen#interpose(a:0 ? a:1 . '/{}' : 'bundle/{}')
+endfunction
+
+if exists(':Vedit')
+  finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd)
+  let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+  let file = pathogen#runtime_findfile(a:file,a:count)
+  if file ==# ''
+    return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+  endif
+  if !s:vopen_warning
+    let s:vopen_warning = 1
+    let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+  else
+    let warning = ''
+  endif
+  if a:lcd
+    let path = file[0:-strlen(a:file)-2]
+    execute 'lcd `=path`'
+    return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+  else
+    return a:cmd.' '.pathogen#fnameescape(file) . warning
+  endif
+endfunction
+
+function! s:Findcomplete(A,L,P)
+  let sep = pathogen#slash()
+  let cheats = {
+        \'a': 'autoload',
+        \'d': 'doc',
+        \'f': 'ftplugin',
+        \'i': 'indent',
+        \'p': 'plugin',
+        \'s': 'syntax'}
+  if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+    let request = cheats[a:A[0]].a:A[1:-1]
+  else
+    let request = a:A
+  endif
+  let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+  let found = {}
+  for path in pathogen#split(&runtimepath)
+    let path = expand(path, ':p')
+    let matches = split(glob(path.sep.pattern),"\n")
+    call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+    call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+    for match in matches
+      let found[match] = 1
+    endfor
+  endfor
+  return sort(keys(found))
+endfunction
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2 foldmethod=expr foldexpr=getline(v\:lnum)=~'^\"\ Section\:'?'>1'\:getline(v\:lnum)=~#'^fu'?'a1'\:getline(v\:lnum)=~#'^endf'?'s1'\:'=':
diff --git a/.vim/bundletab b/.vim/bundletab
new file mode 100644
index 0000000..a2b9c21
--- /dev/null
+++ b/.vim/bundletab
@@ -0,0 +1,14 @@
+# $HOME/.vim/bundletab
+#
+# This file contains a table of vim plugins that are to be installed in the
+# $HOME/.vim/bundle directory. Pathogen will load these as needed.
+#
+# Local name             Remote URL                                      Branch
+#
+feature-camelcasemotion  https://github.com/tyil/camelcasemotion.git     master
+syntax-helm              https://github.com/towolf/vim-helm              master
+syntax-perl6             https://github.com/vim-perl/vim-perl6.git       master
+syntax-terraform         https://github.com/hashivim/vim-terraform       master
+theme-colorsbox          https://github.com/mkarmona/colorsbox.git       master
+theme-jellybeans         https://github.com/nanotech/jellybeans.vim.git  master
+theme-molokai            https://github.com/tomasr/molokai.git           master
diff --git a/.vim/ftplugin/markdown.vim b/.vim/ftplugin/markdown.vim
new file mode 100644
index 0000000..b8df966
--- /dev/null
+++ b/.vim/ftplugin/markdown.vim
@@ -0,0 +1,3 @@
+set shiftwidth=4
+set tabstop=4
+set expandtab
diff --git a/.vim/ftplugin/python.vim b/.vim/ftplugin/python.vim
new file mode 100644
index 0000000..41a06ff
--- /dev/null
+++ b/.vim/ftplugin/python.vim
@@ -0,0 +1 @@
+set foldmethod=indent
diff --git a/.vim/ftplugin/yaml.vim b/.vim/ftplugin/yaml.vim
new file mode 100644
index 0000000..0c0c07f
--- /dev/null
+++ b/.vim/ftplugin/yaml.vim
@@ -0,0 +1,3 @@
+set shiftwidth=2
+set tabstop=2
+set expandtab
diff --git a/.vim/functions/pick-theme.vim b/.vim/functions/pick-theme.vim
new file mode 100644
index 0000000..e601a83
--- /dev/null
+++ b/.vim/functions/pick-theme.vim
@@ -0,0 +1,19 @@
+" PickTheme
+"
+" Pick a customized theme. If no specific theme is given, a random one will be
+" loaded instead.
+"
+" @param string name The name of the theme to load, if any.
+function PickTheme (...)
+	let name = get(a:, 1, "")
+
+	if name
+		exe "ru " . g:path . "/themes/" . name . ".vim"
+		return 0
+	endif
+
+	let s:themes = split(globpath(g:path . "/themes", "*.vim"), "\n")
+	let s:index = system("perl -e 'print int(rand(" . len(s:themes) . "))'")
+
+	exe "so " . s:themes[s:index]
+endfunction
diff --git a/.vim/functions/set-char-limit.vim b/.vim/functions/set-char-limit.vim
new file mode 100644
index 0000000..9269059
--- /dev/null
+++ b/.vim/functions/set-char-limit.vim
@@ -0,0 +1,9 @@
+" SetCharLimit
+"
+" Set's character limit for a file.
+"
+" @param int chars The number of chars to put the limit on.
+function SetCharLimit (chars)
+	exe "set cc=" . a:chars
+	exe "set tw=" . a:chars
+endfunction
diff --git a/.vim/functions/set-indent.vim b/.vim/functions/set-indent.vim
new file mode 100644
index 0000000..8fdc308
--- /dev/null
+++ b/.vim/functions/set-indent.vim
@@ -0,0 +1,19 @@
+" SetIndent
+"
+" Set the size of indents and whether to use tabs or spaces.
+"
+" @param int size The width of the indents.
+" @param bool tabs Whether to use hard tabs or not. Defaults to 1.
+function SetIndent (...)
+	let size = get(a:, 1)
+	let tabs = get(a:, 2, 1)
+
+	if (tabs)
+		set noet
+	else
+		set et
+	endif
+
+	exe "set sw=" . size
+	exe "set ts=" . size
+endfunction
diff --git a/.vim/leaderkeys.vim b/.vim/leaderkeys.vim
new file mode 100644
index 0000000..1848eb4
--- /dev/null
+++ b/.vim/leaderkeys.vim
@@ -0,0 +1,24 @@
+" set leader to space
+let mapleader="\<Space>"
+
+" file exploring
+nmap <Leader>ff :Explore<CR>
+nmap <Leader>fn :Sexplore<CR>
+nmap <Leader>ft :Texplore<CR>
+
+" buffer switching
+nmap <Leader>ww <C-w>w
+nmap <Leader>wh <C-w>h
+nmap <Leader>wj <C-w>j
+nmap <Leader>wk <C-w>k
+nmap <Leader>wl <C-w>l
+
+" building software
+nmap <Leader>cc :w<CR>:make<CR>
+
+" CtrlP
+nmap <Leader>bb :CtrlPBuffer<CR>
+nmap <Leader>fp :CtrlP<CR>
+
+" PDV
+nnoremap <Leader>dg :call pdv#DocumentWithSnip()<CR>
diff --git a/.vim/plugins.vim b/.vim/plugins.vim
new file mode 100644
index 0000000..9027b4f
--- /dev/null
+++ b/.vim/plugins.vim
@@ -0,0 +1,24 @@
+" vim-blade
+au BufNewFile,BufRead *.blade.php set filetype=blade
+
+" git-gutter
+let g:gitgutter_max_signs = 100
+
+" additional syntastic checkers
+let g:syntastic_enable_perl_checker = 1
+let g:syntastic_perl_checkers = ["perl", "perlcritic"]
+
+" set options for syntastic checkers
+let g:syntastic_perl_perlcritic_args = "--brutal"
+
+" enable CamelCaseMotion
+call camelcasemotion#CreateMotionMappings('<silent>')
+
+" Enable unicode abbreviations for prettier Perl 6 code
+let perl6_unicode_abbrevs = 1
+
+" UltiSnips
+let g:snips_author = "Patrick Spek <p.spek@tyil.work>"
+
+" PDV
+let g:pdv_template_dir = $HOME ."/.vim/snippets/php/doc"
diff --git a/.vim/templates/skeleton.sh b/.vim/templates/skeleton.sh
new file mode 100644
index 0000000..df26ef7
--- /dev/null
+++ b/.vim/templates/skeleton.sh
@@ -0,0 +1,10 @@
+#! /usr/bin/env sh
+
+BASEDIR=$(CDPATH="" cd -- "$(dirname -- "$0")" && pwd -P)
+
+main()
+{
+	# TODO
+}
+
+main "$@"
diff --git a/.vim/themes/colorsbox-faff.vim b/.vim/themes/colorsbox-faff.vim
new file mode 100644
index 0000000..9dd00b1
--- /dev/null
+++ b/.vim/themes/colorsbox-faff.vim
@@ -0,0 +1 @@
+colo colorsbox-faff
diff --git a/.vim/themes/jellybeans.vim b/.vim/themes/jellybeans.vim
new file mode 100644
index 0000000..cf14cca
--- /dev/null
+++ b/.vim/themes/jellybeans.vim
@@ -0,0 +1 @@
+colo jellybeans
diff --git a/.vim/themes/molokai.vim b/.vim/themes/molokai.vim
new file mode 100644
index 0000000..29ae0e1
--- /dev/null
+++ b/.vim/themes/molokai.vim
@@ -0,0 +1 @@
+colo molokai
diff --git a/.vim/vimrc b/.vim/vimrc
new file mode 100644
index 0000000..70c83b2
--- /dev/null
+++ b/.vim/vimrc
@@ -0,0 +1,54 @@
+" enable pathogen for plugins
+execute pathogen#infect()
+execute pathogen#helptags()
+
+" enable fancy features
+let g:path = fnamemodify(resolve(expand('<sfile>:p')), ':h')
+
+runtime! functions/*.vim
+
+" vim settings
+set ai
+set cuc
+set cul
+set fdm=syntax
+set lcs=tab:>-,trail:~
+set list
+set lz
+set nu
+set rnu
+set ru
+"set scrolloff=666
+set si
+set sm
+set ut=500
+set wig=*.swp,*.bak,*.pyc,*.class,*.jar,*.gif,*.png,*.jpg,.precomp
+set wmnu
+
+call PickTheme()
+call SetCharLimit(79)
+call SetIndent(3)
+
+" add hotkeys
+nmap <F6> :make<CR>
+
+" set normal numbering in insert
+au InsertEnter * :set nornu
+au InsertLeave * :set rnu
+
+" enable views by default
+"au BufWinLeave ?* mkview
+"au BufWinEnter ?* silent loadview
+
+" sudo write
+ca w!! w !sudo tee > /dev/null "%"
+
+" Persistent undo
+if has("persistent_undo")
+	set undodir=~/.cache/neovim/undo
+	set undolevels=1000
+	set undofile
+endif
+
+ru leaderkeys.vim
+ru plugins.vim