aboutsummaryrefslogtreecommitdiff
path: root/lib/GUI/Tk.rakumod
blob: 3a2e463e5fc22d4b1983fcf5433540949093ee9d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
#! /usr/bin/env false

use v6.d;

use GUI::TkWidget;
use GUI::Tk::Button;

unit class GUI::Tk;

#| Boolean deciding whether to output debug information.
has Bool $.debug = False;

#| The promise container. This allows easy access to the promise later on.
has Promise $!promise;

#| The wish process container.
has Proc::Async $!wish;

#| A Hash of callback triggers and Callables.
has %!callbacks;

#| A Channel to handle retrieval of variables.
has %!variables;

#| Returns the Promise object of the started wish proces..
method promise ()
{
	$!promise
}

#| Send a command to wish.
multi method cmd (
	Str:D $command is copy,
) {
	say "% $command" if $!debug;
	$!wish.say($command);
}

multi method cmd (
	GUI::TkWidget:D $widget,
	*%args,
) {
	samewith($widget.compile, |%args);
}

multi method cmd (
	GUI::TkWidgetCompiled:D $widget,
	*%args,
) {
	# Add a callback if needed
	if ($widget.trigger && $widget.callback) {
		%!callbacks{$widget.trigger} = $widget.callback;
	}

	samewith($widget.command);
}

#
# Convenience methods
#

method bind (
	Str:D $path,
	Str:D $key,
	&callback,
) {
	my $trigger = &callback.WHICH.Str;
	my $command = GUI::TkWidgetCompiled.new(
		command => qq[bind $path $key \{puts "CALLBACK $trigger"}],
		:$trigger,
		:&callback,
	);

	self.cmd($command);
}

method focus (
	Str:D $path
) {
	self.cmd("focus $path")
}

multi method grid (
	Int:D $x,
	Int:D $y,
	GUI::TkWidget $widget,
	*%args,
) {
	samewith($x, $y, $widget.compile, |%args)
}

multi method grid (
	Int:D $x,
	Int:D $y,
	GUI::TkWidgetCompiled $widget,
	*%args,
) {
	my $command = "grid [{$widget.command}]";

	%args<column> = $x;
	%args<row> = $y;

	$command ~= ' ' ~ %args.kv.map(sub ($k, $v) { "-$k {$v.raku}" }).join(' ');

	self.cmd($command);
}

method title (
	Str:D $title,
	Str:D $path = '.',
) {
	self.cmd("wm title $path {$title.raku}");
}

method var (
	Str:D $name,
	--> Promise
) {
	start {
		my $channel := %!variables{$name};

		# Create the channel if needed
		$channel //= Channel.new;

		# Print a VARIABLE to stdout
		self.cmd(qq[puts "VARIABLE $name \$::$name"]);

		# Wait for that VARIABLE to appear
		my $value = $channel.receive.first;

		# Return the found value
		$value;
	}
}

submethod TWEAK
{
	$!wish = Proc::Async.new(%*ENV<RAKU_GUI_WISH_BIN> // 'wish', :w);
	$!wish.stdout.tap(sub ($line) {
		say "< {$line.trim}" if $!debug;

		my @words = $line.words;

		given (@words.first) {
			when 'CALLBACK' {
				%!callbacks{@words[1]}()
			}
			when 'VARIABLE' {
				if (%!variables{@words[1]} ~~ Channel:D) {
					%!variables{@words[1]}.send(@words[2..*])
				}
			}
		}
	});

	$!promise = $!wish.start;
}

=begin pod

=NAME    GUI::Tk
=VERSION 0.0.0
=AUTHOR  Patrick Spek <p.spek@tyil.nl>

=begin LICENSE
Copyright © 2020

This program is free software: you can redistribute it and/or modify it under
the terms of the GNU Affero General Public License as published by the Free
Software Foundation, either version 3 of the License, or (at your option) any
later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
details.

You should have received a copy of the GNU Affero General Public License along
with this program.  If not, see http://www.gnu.org/licenses/.
=end LICENSE

=end pod

# vim: ft=raku noet sw=8 ts=8