aboutsummaryrefslogtreecommitdiff
path: root/lib/IRC/Client/Plugin/DiceRolls.rakumod
blob: 8d94e61efac01580547e119882a36f68352c9a6d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
#! /usr/bin/env false

use v6.d;

use Config;
use Grammar::DiceRolls;
use Grammar::DiceRolls::CountActions;
use Grammar::DiceRolls::ListActions;
use IRC::Client;
use X::Grammar::DiceRolls::TooManyDice;
use X::Grammar::DiceRolls::TooManySides;

unit class IRC::Client::Plugin::DiceRolls does IRC::Client::Plugin;

#| A Config instance to hold all configuration.
has Config $.config;

#| The calculated prefix for the dice roll command.
has Str $!prefix;

submethod TWEAK
{
	$!prefix = [~]
		$!config.get('irc.command-prefix', '.'),
		$!config.get('irc.plugins.dicerolls.command-word', 'roll'),
		;
}

method reload-config (
	Config $config,
) {
	$!config = $config;

	self.TWEAK;
}

multi method irc-privmsg (
	$event where { $event.text.starts-with($!prefix) }
) {
	my $roll = $event.text.substr($!prefix.chars).trim || '1d20';

	.debug("Rolling for $roll") with $*LOG;

	given ($!config.get('irc.plugins.dicerolls.style', 'list').fc) {
		when 'list' {
			my @outcomes = Grammar::DiceRolls.parse(
				$roll,
				:actions(Grammar::DiceRolls::ListActions.new(
					limit-dice => $!config.get('irc.plugins.dicerolls.limit-dice', 30),
					limit-sides => $!config.get('irc.plugins.dicerolls.limit-sides', 1_000_000_000),
				))
			).made;

			return "Invalid roll ($roll)" unless @outcomes;
			return "$roll = {@outcomes.first}" if @outcomes.elems < 2;
			return "$roll = {@outcomes.join(' + ')} = {@outcomes.sum}";
		}
		when 'count' {
			my $outcome = Grammar::DiceRolls.parse(
				$roll,
				:actions(Grammar::DiceRolls::CountActions)
			).made;

			return "Invalid roll ($roll)" unless $outcome;
			return "$roll = $outcome";
		}
		default {
			.alert('Invalid rolling style for irc.plugins.dicerolls.style') with $*LOG;
		}
	}

	CATCH {
		when X::Grammar::DiceRolls::TooManyDice {
			.error("Too many dice in $roll") with $*LOG;
			return 'No dice';
		}
		when X::Grammar::DiceRolls::TooManySides {
			.error("Too many sides in $roll") with $*LOG;
			return 'No dice';
		}
	}
}

=begin pod

=NAME    IRC::Client::Plugin::DiceRolls
=VERSION 0.2.0
=AUTHOR  Patrick Spek <p.spek@tyil.nl>

=begin LICENSE
Copyright © 2020

This program is free software: you can redistribute it and/or modify it under
the terms of the GNU Affero General Public License as published by the Free
Software Foundation, either version 3 of the License, or (at your option) any
later version.

This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
details.

You should have received a copy of the GNU Affero General Public License along
with this program.  If not, see http://www.gnu.org/licenses/.
=end LICENSE

=end pod

# vim: ft=raku noet sw=8 ts=8