aboutsummaryrefslogtreecommitdiff
path: root/lib/IRC/Client
diff options
context:
space:
mode:
Diffstat (limited to 'lib/IRC/Client')
-rw-r--r--lib/IRC/Client/Core.rakumod155
-rw-r--r--lib/IRC/Client/Grammar.pm626
-rw-r--r--lib/IRC/Client/Grammar/Actions.pm6119
-rw-r--r--lib/IRC/Client/Handler.rakumod174
-rw-r--r--lib/IRC/Client/Message.pm679
-rw-r--r--lib/IRC/Client/Message.rakumod180
-rw-r--r--lib/IRC/Client/Plugin.rakumod28
-rw-r--r--lib/IRC/Client/Server.pm620
8 files changed, 537 insertions, 244 deletions
diff --git a/lib/IRC/Client/Core.rakumod b/lib/IRC/Client/Core.rakumod
new file mode 100644
index 0000000..8cba445
--- /dev/null
+++ b/lib/IRC/Client/Core.rakumod
@@ -0,0 +1,155 @@
+#! /usr/bin/env false
+
+use v6.d;
+
+use IRC::Client::Handler;
+use IRC::Client::Plugin;
+use Log;
+
+#| A plugin for IRC::Client, encapsulating all the core functionality required
+#| of a functional IRC client.
+unit class IRC::Client::Core is IRC::Client::Plugin;
+
+#| Special cased method to setup the initial connection with IRC.
+multi method irc-setup ($irc) {
+ $irc.connected = True;
+ $irc.send-raw("USER {$irc.user} 8 * :{$irc.real-name}");
+ $irc.set-nick($irc.nicks[0]);
+}
+
+#| Special cased method to perform actions once the client is ready to go to
+#| work.
+multi method irc-ready ($irc) {
+ for $irc.channels -> $channel {
+ $irc.join($channel);
+ }
+}
+
+#| Handle RPL_WELCOME. This message indicates that the connection setup has
+#| been succesful.
+multi method irc-n001 ($message) {
+ my $nick = $message.params[0];
+
+ .debug("Logged in as $nick") with $Log::instance;
+
+ $.irc.prefix = $message[*-1].words.tail;
+ $.irc.nick = $nick;
+}
+
+#| Handle ERR_ERRONEUSNICKNAME. This message indicates that the nickname which
+#| is being used is not allowed, and the client should try an alternative
+#| instead.
+multi method irc-n432 ($message where { $_.params[0] eq '*' }) {
+ .error($message.params[*-1]) with $Log::instance;
+
+ my @nicks = $.irc.nicks;
+ my $index = @nicks.first($.irc.nick, :k) + 1 // 0;
+
+ if (@nicks.elems ≤ $index) {
+ .warning("No more nicks to try ({@nicks.join(' ')})") with $Log::instance;
+ $.irc.stop;
+ exit(3);
+ }
+
+ $.irc.set-nick(@nicks[$index]);
+}
+
+#| Handle ERR_NICKNAMEINUSE. This message indicates the nickname which is being
+#| used is already in use by another client. Another nickname should be tried
+#| instead.
+multi method irc-n433 ($message where { $_.params[0] eq '*' }) {
+ self.irc-n432($message);
+}
+
+multi method irc-n433 ($message where { $_.params[0] ne '*'}) {
+ $.irc.nick = $_.params[1];
+}
+
+#| Handle ERR_CHANNELISFULL. This message indicates a channel could not be
+#| joined due to a user count limitation (+l).
+multi method irc-n471 ($message) {
+ self!unregister-channel($.irc, $message.params[1]);
+}
+
+#| Handle ERR_INVITEONLYCHAN. This message indicates a channel could not be
+#| joined because you must be invited (+i).
+multi method irc-n473 ($message) {
+ self!unregister-channel($message.params[1]);
+}
+
+#| Handle ERR_BANNEDFROMCHAN. This message indicates a channel could not be
+#| joined due to an active ban (+b).
+multi method irc-n474 ($message) {
+ self!unregister-channel($message.params[1]);
+}
+
+#| Handle ERR_BADCHANNELKEY. This message indicates a channel could not be
+#| joined because it requires a key, or the given key was incorrect.
+multi method irc-n475 ($message) {
+ self!unregister-channel($message.params[1]);
+}
+
+#| Handle JOIN, but only if it pertains to ourselves. This method will keep the
+#| IRC::Client.channels list synced to the channels the bot is actually in.
+multi method irc-join ($message where { $_.nickname eq $message.irc.nick }) {
+ self!register-channel($message.params[0]);
+}
+
+#| Handle PART, but only if it pertains to ourselves. This method will keep the
+#| IRC::Client.channels list synced to the channels the bot is actually in.
+multi method irc-part ($message where { $_.nickname eq $message.irc.nick }) {
+ self!unregister-channel($message.params[0]);
+}
+
+#| Handle a CTCP PING request.
+multi method irc-privmsg ($message where { $_.ctcp && $_.params[*-1].words[0] eq 'PING'}) {
+ $.irc.notice($message.nickname, "PING {$message.params[*-1].words[1..*]}", :ctcp);
+}
+
+#| Handle a CTCP VERSION request.
+multi method irc-privmsg ($message where { $_.ctcp && $_.params[*-1].words[0] eq 'VERSION'}) {
+ $.irc.notice($message.nickname, 'VERSION raku/IRC::Client v0.1.0', :ctcp);
+}
+
+#| Handle a PING command. This message should be responded to with a PONG
+#| reply, to indicate the client is still alive.
+multi method irc-ping ($message) {
+ $.irc.send-raw("PONG :{$message.params[*-1]}");
+}
+
+#| Convenience method for adding a channel to the IRC::Client.channels list.
+method !register-channel ($channel) {
+ my @channels = $.irc.channels;
+
+ return if @channels ∋ $channel;
+
+ .debug("Adding $channel to the IRC::Client.channels") with $Log::instance;
+
+ $.irc.channels.append($channel);
+}
+
+#| Convenience method for removing a channel from the IRC::Client.channels
+#| list.
+method !unregister-channel ($channel) {
+ .debug("Removing $channel from IRC::Client.channels") with $Log::instance;
+
+ $.irc.channels = $.irc.channels.grep(* ne $channel);
+}
+
+=begin pod
+
+=NAME IRC::Client::Core
+=AUTHOR Patrick Spek <~tyil/raku-devel@lists.sr.ht>
+=VERSION 0.0.0
+
+=head1 Synopsis
+
+=head1 Description
+
+=head1 Examples
+
+=head1 See also
+
+=end pod
+
+# vim: ft=perl6 noet
diff --git a/lib/IRC/Client/Grammar.pm6 b/lib/IRC/Client/Grammar.pm6
deleted file mode 100644
index 9afecc7..0000000
--- a/lib/IRC/Client/Grammar.pm6
+++ /dev/null
@@ -1,26 +0,0 @@
-unit grammar IRC::Client::Grammar;
-token TOP { <message>+ <left-overs> }
-token left-overs { \N* }
-token SPACE { ' '+ }
-token message { [':' <prefix> <SPACE> ]? <command> <params> \n }
- regex prefix {
- [ <servername> || <nick> ['!' <user>]? ['@' <host>]? ]
- <before <SPACE>>
- }
- token servername { <host> }
- token nick {
- # the RFC grammar states nicks have to start with a letter,
- # however, modern server support and nick use disagrees with that
- # and nicks can start with special chars too
- [<letter> | <special>] [ <letter> | <number> | <special> ]*
- }
- token user { <-[\ \x[0]\r\n]>+? <before [<SPACE> | '@']>}
- token host { <-[\s!@]>+ }
- token command { <letter>+ | <number>**3 }
- token params { <SPACE>* [ ':' <trailing> | <middle> <params> ]? }
- token middle { <-[:\ \x[0]\r\n]> <-[\ \x[0]\r\n]>* }
- token trailing { <-[\x[0]\r\n]>* }
-
- token letter { <[a..zA..Z]> }
- token number { <[0..9]> }
- token special { <[-_\[\]\\`^{}|]> }
diff --git a/lib/IRC/Client/Grammar/Actions.pm6 b/lib/IRC/Client/Grammar/Actions.pm6
deleted file mode 100644
index b1fcc53..0000000
--- a/lib/IRC/Client/Grammar/Actions.pm6
+++ /dev/null
@@ -1,119 +0,0 @@
-unit class IRC::Client::Grammar::Actions;
-
-use IRC::Client::Message;
-
-has $.irc;
-has $.server;
-
-method TOP ($/) {
- $/.make: (
- $<message>».made,
- ~( $<left-overs> // '' ),
- );
-}
-
-method message ($match) {
- my %args;
- my $pref = $match<prefix>;
- for qw/nick user host/ {
- $pref{$_}.defined or next;
- %args<who>{$_} = ~$pref{$_};
- }
- %args<who><host> = ~$pref<servername> if $pref<servername>.defined;
-
- my $p = $match<params>;
- loop {
- %args<params>.append: ~$p<middle> if $p<middle>.defined;
-
- if ( $p<trailing>.defined ) {
- %args<params>.append: ~$p<trailing>;
- last;
- }
- last unless $p<params>.defined;
- $p = $p<params>;
- }
-
- my %msg-args =
- command => $match<command>.uc,
- args => %args<params>,
- host => %args<who><host>//'',
- irc => $!irc,
- nick => %args<who><nick>//'',
- server => $!server,
- usermask => ~($match<prefix>//''),
- username => %args<who><user>//'';
-
- my $msg;
- given %msg-args<command> {
- when /^ <[0..9]>**3 $/ {
- $msg = IRC::Client::Message::Numeric.new: |%msg-args;
- }
- when 'JOIN' {
- $msg = IRC::Client::Message::Join.new:
- :channel( %args<params>[0] ),
- |%msg-args;
- }
- when 'PART' {
- $msg = IRC::Client::Message::Part.new:
- :channel( %args<params>[0] ),
- |%msg-args;
- }
- when 'NICK' {
- $msg = IRC::Client::Message::Nick.new:
- :new-nick( %args<params>[0] ),
- |%msg-args;
- }
- when 'NOTICE' { $msg = msg-notice %args, %msg-args }
- when 'MODE' { $msg = msg-mode %args, %msg-args }
- when 'PING' { $msg = IRC::Client::Message::Ping.new: |%msg-args }
- when 'PRIVMSG' { $msg = msg-privmsg %args, %msg-args }
- when 'QUIT' { $msg = IRC::Client::Message::Quit.new: |%msg-args }
- default { $msg = IRC::Client::Message::Unknown.new: |%msg-args }
- }
-
- $match.make: $msg;
-}
-
-sub msg-privmsg (%args, %msg-args) {
- %args<params>[0] ~~ /^<[#&]>/
- and return IRC::Client::Message::Privmsg::Channel.new:
- :channel( %args<params>[0] ),
- :text( %args<params>[1] ),
- |%msg-args;
-
- return IRC::Client::Message::Privmsg::Me.new:
- :text( %args<params>[1] ),
- |%msg-args;
-}
-
-sub msg-notice (%args, %msg-args) {
- %args<params>[0] ~~ /^<[#&]>/
- and return IRC::Client::Message::Notice::Channel.new:
- :channel( %args<params>[0] ),
- :text( %args<params>[1] ),
- |%msg-args;
-
- return IRC::Client::Message::Notice::Me.new:
- :text( %args<params>[1] ),
- |%msg-args;
-}
-
-sub msg-mode (%args, %msg-args) {
- if %args<params>[0] ~~ /^<[#&]>/ {
- my @modes;
- for %args<params>[1..*-1].join.comb: /\S/ {
- state $sign;
- /<[+-]>/ and $sign = $_ and next;
- @modes.push: $sign => $_;
- };
- return IRC::Client::Message::Mode::Channel.new:
- :channel( %args<params>[0] ),
- :modes( @modes ),
- |%msg-args;
- }
- else {
- return IRC::Client::Message::Mode::Me.new:
- :modes( %args<params>[1..*-1].join.comb: /<[a..zA..Z]>/ ),
- |%msg-args;
- }
-}
diff --git a/lib/IRC/Client/Handler.rakumod b/lib/IRC/Client/Handler.rakumod
new file mode 100644
index 0000000..c966099
--- /dev/null
+++ b/lib/IRC/Client/Handler.rakumod
@@ -0,0 +1,174 @@
+#! /usr/bin/env false
+
+use v6.d;
+
+use IRC::Client::Message;
+use IRC::Client::Plugin;
+
+use Log;
+
+#| This class handles incoming messages, formats a context from them and
+#| dispatches it on to any registered plugin that can handle it.
+unit class IRC::Client::Handler;
+
+#| Handle numeric commands.
+multi method handle (
+ $event where { $_.command ~~ / \d ** 3/ },
+) {
+ my @events;
+
+ # Special cases for IRC::Client
+ @events.append('irc-connected' => $event.irc) if $event.command eq '001';
+ @events.append('irc-ready' => $event.irc) if $event.command eq '376';
+ @events.append('irc-ready' => $event.irc) if $event.command eq '422';
+
+ # Regular events, handles in the regular way
+ @events.append("irc-n{$event.command}" => $event);
+ @events.append('irc-numeric' => $event);
+ @events.append('irc-all' => $event);
+
+ self.dispatch(@events, $event.irc);
+}
+
+#| Handle PRIVMSG and NOTICE commands.
+multi method handle (
+ $event where { $_.command ∈ <PRIVMSG NOTICE> }
+) {
+ my @events;
+ my $stripped;
+
+ # If the message starts with the name of the client, it should dispatch
+ # an irc-addressed event.
+ if ($event.params[*-1] ~~ / ^ ( "{$event.irc.nick}" <[:;,]> <.ws> ) /) {
+ $stripped = $event.set-param(*-1, $event.params[*-1].substr($0.chars));
+ }
+
+
+ # A private message to the client should dispatch an irc-to-me event,
+ # optionally stripping away the client's current nickname from the
+ # start.
+ if ($event.params[0] eq $event.irc.nick) {
+ @events.append('irc-to-me' => $stripped // $event);
+ }
+
+ # A message to a public channel prefixed with the client's current
+ # nickname is both an irc-to-me event, and an irc-addressed event.
+ if ($event.params[0] ne $event.irc.nick && $stripped) {
+ @events.append('irc-to-me' => $stripped);
+ @events.append('irc-addressed' => $stripped);
+ }
+
+ @events.append("irc-{$event.command.fc}-me" => $event) if $event.params[0] eq $event.irc.nick;
+ @events.append('irc-mentioned' => $event) if $event.params[*-1].words ∋ $event.irc.nick;
+ @events.append("irc-{$event.command.fc}-channel" => $event) if $event.params[0] ~~ / ^ <[#&]> /;
+ @events.append("irc-{$event.command.fc}" => $event);
+ @events.append('irc-all' => $event);
+
+ self.dispatch(@events, $event.irc);
+}
+
+#| Handle MODE commands.
+multi method handle (
+ $event where { $_.command eq 'MODE' }
+) {
+ my @events;
+
+ @events.append('irc-mode-me' => $event) if $event.params[0] eq $event.irc.nick;
+ @events.append('irc-mode-channel' => $event) if $event.params[0] ~~ / ^ <[#&]> /;
+ @events.append('irc-mode' => $event);
+ @events.append('irc-all' => $event);
+
+ self.dispatch(@events, $event.irc);
+}
+
+#| Handle all IRC commands. Note that the order in which events are appended
+#| does matter, the most "narrow" event should always come first, getting
+#| broader as we go down the list.
+multi method handle (
+ $event,
+) {
+ my @events;
+
+ @events.append("irc-{$event.command.fc}" => $event);
+ @events.append('irc-all' => $event);
+
+ self.dispatch(@events, $event.irc);
+}
+
+#| Dispatch the message to all plugins.
+method dispatch (
+ @events,
+ $client, #= IRC::Client, but can't `use` this due to circular references
+) {
+ my @plugins = $client.plugins;
+
+ # Loop over all the plugins, and dispatch to each of them on a seperate
+ # thread. This allows plugins to take their sweet time, while not being
+ # in any other plugins' way.
+ for $client.plugins -> $plugin {
+ start {
+ CATCH {
+ default {
+ my $exception = $_;
+ .emergency($exception.gist.lines.map(*.trim-trailing).join("\n")) with $Log::instance;
+ }
+ }
+
+ self.dispatch-plugin(@events, $plugin)
+ }
+ }
+}
+
+#| Dispatch the message to all plugin methods that can handle them.
+method dispatch-plugin (
+ @events,
+ IRC::Client::Plugin $plugin,
+) {
+ for @events -> $event {
+ my $method = $event.key;
+ my $payload = $event.value;
+
+ # Check for available methods to handle this payload.
+ my @methods = $plugin.^can($method)
+ .map(*.candidates)
+ .flat
+ .grep(*.cando(\($plugin, $payload)))
+ ;
+
+ # Nothing to do if nothing was found.
+ next unless @methods;
+
+ .debug("Dispatching to {$plugin.^name}.$method") with $Log::instance;
+
+ my $response = $plugin."$method"($payload);
+
+ next unless $payload ~~ IRC::Client::Message;
+
+ # Depending on the return value of the method, something can be
+ # done.
+ given ($response) {
+ when Str {
+ $payload.reply($response);
+ last;
+ }
+ }
+ }
+}
+
+=begin pod
+
+=NAME IRC::Client::Handler
+=AUTHOR Patrick Spek <~tyil/raku-devel@lists.sr.ht>
+=VERSION 0.0.0
+
+=head1 Synopsis
+
+=head1 Description
+
+=head1 Examples
+
+=head1 See also
+
+=end pod
+
+# vim: ft=perl6 noet
diff --git a/lib/IRC/Client/Message.pm6 b/lib/IRC/Client/Message.pm6
deleted file mode 100644
index ff307ef..0000000
--- a/lib/IRC/Client/Message.pm6
+++ /dev/null
@@ -1,79 +0,0 @@
-unit package IRC::Client::Message;
-
-role IRC::Client::Message {
- has $.irc is required;
- has Str:D $.nick is required;
- has Str:D $.username is required;
- has Str:D $.host is required;
- has Str:D $.usermask is required;
- has Str:D $.command is required;
- has $.server is required;
- has $.args is required;
-
- method Str { ":$!usermask $!command $!args[]" }
-}
-
-constant M = IRC::Client::Message;
-
-role Join does M { has $.channel; }
-role Mode does M { has @.modes; }
-role Mode::Channel does Mode { has $.channel; }
-role Mode::Me does Mode { }
-role Nick does M { has $.new-nick; }
-role Numeric does M { }
-role Part does M { has $.channel; }
-role Quit does M { }
-role Unknown does M {
- method Str { "❚⚠❚ :$.usermask $.command $.args[]" }
-}
-
-role Ping does M {
- method reply { $.irc.send-cmd: 'PONG', $.args, :$.server; }
-}
-
-role Privmsg does M {
- has $.text is rw;
- has Bool $.replied is rw = False;
- method Str { $.text }
- method match ($v) { $.text ~~ $v }
-}
-role Privmsg::Channel does Privmsg {
- has $.channel;
- method reply ($text, :$where) {
- $.irc.autoprefix
- ?? $.irc.send-cmd: 'PRIVMSG', $where // $.channel, $text, :$.server, :prefix("$.nick, ")
- !! $.irc.send-cmd: 'PRIVMSG', $where // $.channel, $text, :$.server
- ;
- }
-}
-role Privmsg::Me does Privmsg {
- method reply ($text, :$where) {
- $.irc.send-cmd: 'PRIVMSG', $where // $.nick, $text,
- :$.server;
- }
-}
-
-role Notice does M {
- has $.text is rw;
- has Bool $.replied is rw = False;
- method Str { $.text }
- method match ($v) { $.text ~~ $v }
-}
-role Notice::Channel does Notice {
- has $.channel;
- method reply ($text, :$where) {
- $.irc.autoprefix
- ?? $.irc.send-cmd: 'NOTICE', $where // $.channel, $text, :$.server, :prefix("$.nick, ")
- !! $.irc.send-cmd: 'NOTICE', $where // $.channel, $text, :$.server
- ;
-
- $.replied = True;
- }
-}
-role Notice::Me does Notice {
- method reply ($text, :$where) {
- $.irc.send-cmd: 'NOTICE', $where // $.nick, $text,
- :$.server;
- $.replied = True;
- }
-}
diff --git a/lib/IRC/Client/Message.rakumod b/lib/IRC/Client/Message.rakumod
new file mode 100644
index 0000000..1e1ffb7
--- /dev/null
+++ b/lib/IRC/Client/Message.rakumod
@@ -0,0 +1,180 @@
+#! /usr/bin/env false
+
+use v6.d;
+
+use IRC::Grammar;
+
+#| A class to represent a message over IRC.
+unit class IRC::Client::Message;
+
+has Str $.servername;
+has Str $.nickname;
+has Str $.user;
+has Str $.host;
+has Str $.command;
+has Str @.params;
+has Bool $.ctcp = False;
+has $.irc;
+
+multi method new (
+ #| A string representing a line sent or received from an IRC server.
+ Str:D $line,
+
+ #| A reference the the IRC::Client handling the message.
+ $irc,
+) {
+ my $match = IRC::Grammar.parse($line);
+
+ # If the line doesn't match the IRC grammar, it's malformed and not up
+ # to IRC::Client to fix it.
+ die "Malformed message '$line'" if !?$match;
+
+ my $ctcp = False;
+ my @params = $match<params>.map(*.Str).Array;
+
+ my %prefix = $match<prefix>
+ .hash
+ .kv
+ .map(sub ($key, $value) { $key => $value.Str })
+ ;
+
+ if ($match<command> eq 'PRIVMSG'|'NOTICE') {
+ with ($match<params>.tail.Str) {
+ if ($_.comb[0, *-1].grep(* eq "\x[1]")) {
+ $ctcp = True;
+ @params[*-1] = $_.Str.substr(1, *-1);
+ } else {
+ @params[*-1] = $_.Str;
+ }
+ }
+ }
+
+ self.bless(
+ command => $match<command>.Str,
+ |%prefix,
+ :@params,
+ :$irc,
+ );
+}
+
+multi method new (
+ %params,
+) {
+ self.bless(|%params, params => %params<params>.list);
+}
+
+method gist
+{
+ @!params.tail
+}
+
+method prefix
+{
+ return $!servername if $!servername;
+
+ my $prefix = $!nickname;
+
+ if ($!host) {
+ if ($!user) {
+ $prefix = "$prefix!$!user";
+ }
+
+ $prefix = "$prefix@$!host";
+ }
+
+ $prefix;
+}
+
+method raku
+{
+ my $s = "$!command {@!params.join(' ')}";
+
+ with (self.prefix) { $s = ":$_ $s" }
+
+ given (@!params.elems) {
+ when 1 {
+ $s = "$s :{@!params[0]}"
+ }
+ default {
+ my @middle = @!params.head(*-1);
+ my $trailing = @!params.tail;
+
+ $s = "$s {@middle.join(' ')} :$trailing";
+ }
+ }
+
+
+ $s;
+}
+
+method words
+{
+ self.Str.words
+}
+
+method Hash
+{
+ %(
+ :$!servername,
+ :$!nickname,
+ :$!user,
+ :$!host,
+ :$!command,
+ :@!params,
+ :$!ctcp,
+ :$!irc,
+ )
+}
+
+method Str
+{
+ self.gist
+}
+
+#
+# Mutators
+#
+
+method set-param (
+ $index where { $_ ~~ Int:D|Code:D },
+ Str:D $value,
+) {
+ my %params = self.Hash;
+
+ %params<params>[$index] = $value;
+
+ self.new(|%params, params => %params<params>.list);
+}
+
+#
+# Convenience
+#
+
+method reply (
+ Str:D $message,
+) {
+ my $target = @!params[0] eq $!irc.nick ?? $!nickname !! @!params[0];
+
+ given ($!command) {
+ when 'PRIVMSG' { $!irc.privmsg($target, $message, :$!ctcp) }
+ when 'NOTICE' { $!irc.notice($target, $message, :$!ctcp) }
+ }
+}
+
+=begin pod
+
+=NAME IRC::Client::Message
+=AUTHOR Patrick Spek <~tyil/raku-devel@lists.sr.ht>
+=VERSION 0.0.0
+
+=head1 Synopsis
+
+=head1 Description
+
+=head1 Examples
+
+=head1 See also
+
+=end pod
+
+# vim: ft=perl6 noet
diff --git a/lib/IRC/Client/Plugin.rakumod b/lib/IRC/Client/Plugin.rakumod
new file mode 100644
index 0000000..7388416
--- /dev/null
+++ b/lib/IRC/Client/Plugin.rakumod
@@ -0,0 +1,28 @@
+#! /usr/bin/env false
+
+use v6.d;
+
+#| A base role for IRC::Client plugins. A plugin may handle any number of
+#| methods, in order to act upon events encountered by the client.
+unit role IRC::Client::Plugin;
+
+#| A reference to the IRC::Client the plugin is used by.
+has $.irc is rw;
+
+=begin pod
+
+=NAME IRC::Client::Plugin
+=AUTHOR Patrick Spek <~tyil/raku-devel@lists.sr.ht>
+=VERSION 0.0.0
+
+=head1 Synopsis
+
+=head1 Description
+
+=head1 Examples
+
+=head1 See also
+
+=end pod
+
+# vim: ft=perl6 noet
diff --git a/lib/IRC/Client/Server.pm6 b/lib/IRC/Client/Server.pm6
deleted file mode 100644
index 18f7755..0000000
--- a/lib/IRC/Client/Server.pm6
+++ /dev/null
@@ -1,20 +0,0 @@
-unit class IRC::Client::Server;
-
-has @.channels where .all ~~ Str|Pair;
-has @.nick where .all ~~ Str;
-has @.alias where .all ~~ Str|Regex;
-has Int $.port where 0 <= $_ <= 65535;
-has Bool $.ssl = False;
-has Str $.ca-file;
-has Str $.label;
-has Str $.host;
-has Str $.password;
-has Str $.username;
-has Str $.userhost;
-has Str $.userreal;
-has Str $.current-nick is rw;
-has Bool $.is-connected is rw;
-has Bool $.has-quit is rw;
-has $.socket is rw;
-
-method Str { $!label }
generated by cgit v1.1 at 2024-05-18 15:55:01 +0000